OBJ_ARROWED_LINE
箭头线。
示例
下面的脚本创建和移动图表上的箭头线。已开发的特别函数用于创建和改变图形对象的属性。您可以在您的个人应用中使用这些函数"as is" 。
//--- 描述
#property description "Script draws \"Arrowed line\" graphical object."
#property description "Anchor point coordinates are set in percentage of"
#property description "the chart window size."
//--- 启动脚本期间显示输入参数的窗口
#property script_show_inputs
//--- 脚本的输入参数
input string InpName="ArrowedLine"; // 线的名称
input int InpDate1=35; // 第1个点的日期，%
input int InpPrice1=60; // 第1个点的价格，%
input int InpDate2=65; // 第2个点的日期，%
input int InpPrice2=40; // 第2个点的价格，%
input color InpColor=clrRed; // 线的颜色
input ENUM_LINE_STYLE InpStyle=STYLE_DASH; // 线的风格
input int InpWidth=2; // 线的宽度
input bool InpBack=false; // 背景线
input bool InpSelection=true; // 突出移动
input bool InpHidden=true; // 隐藏在对象列表
input long InpZOrder=0; // 鼠标单击优先
//+------------------------------------------------------------------+
//| 通过已给的坐标创建箭头线 |
//+------------------------------------------------------------------+
bool ArrowedLineCreate(const long chart_ID=0, // 图表 ID
const string name="ArrowedLine", // 线的名称
const int sub_window=0, // 子窗口指数
datetime time1=0, // 第一个点的时间
double price1=0, // 第一个点的价格
datetime time2=0, // 第二个点的时间
double price2=0, // 第二个点的价格
const color clr=clrRed, // 线的颜色
const ENUM_LINE_STYLE style=STYLE_SOLID, // 线的风格
const int width=1, // 线的宽度
const bool back=false, // 在背景中
const bool selection=true, // 突出移动
const bool hidden=true, // 隐藏在对象列表
const long z_order=0) // 鼠标单击优先
{
//--- 若未设置则设置定位点的坐标
ChangeArrowedLineEmptyPoints(time1,price1,time2,price2);
//--- 重置错误的值
ResetLastError();
//--- 通过已给的坐标创建箭头线
if(!ObjectCreate(chart_ID,name,OBJ_ARROWED_LINE,sub_window,time1,price1,time2,price2))
{
Print(__FUNCTION__,
": failed to create an arrowed line! Error code = ",GetLastError());
return(false);
}
//--- 设置线的颜色
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- 设置线的显示风格
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- 设置线的宽度
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- 显示前景 (false) 或背景 (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- 启用 (true) 或禁用 (false) 通过鼠标移动线的模式
//--- 当使用ObjectCreate函数创建图形对象时，对象不能
//--- 默认下突出并移动。在这个方法中，默认选择参数
//--- true 可以突出移动对象
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- 在对象列表隐藏(true) 或显示 (false) 图形对象名称
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- 设置在图表中优先接收鼠标点击事件
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 成功执行
return(true);
}
//+------------------------------------------------------------------+
//| 移动箭头线的定位点 |
//+------------------------------------------------------------------+
bool ArrowedLinePointChange(const long chart_ID=0, // 图表 ID
const string name="ArrowedLine", // 线的名称
const int point_index=0, // 定位点指数
datetime time=0, // 定位点时间坐标
double price=0) // 定位点价格坐标
{
//--- 如果没有设置点的位置，则将其移动到当前的卖价柱
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- 重置错误的值
ResetLastError();
//--- 移动线的定位点
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
": failed to move the anchor point! Error code = ",GetLastError());
return(false);
}
//--- 成功执行
return(true);
}
//+------------------------------------------------------------------+
//| 这个函数移除图表的箭头线 |
//+------------------------------------------------------------------+
bool ArrowedLineDelete(const long chart_ID=0, // 图表 ID
const string name="ArrowedLine") // 线的名称
{
//--- 重置错误的值
ResetLastError();
//--- 删除箭头线
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": failed to create an arrowed line! Error code = ",GetLastError());
return(false);
}
//--- 成功执行
return(true);
}
//+------------------------------------------------------------------+
//| 检查定位点的值和为空点设置 |
//| 默认的值 |
//+------------------------------------------------------------------+
void ChangeArrowedLineEmptyPoints(datetime &time1,double &price1,
datetime &time2,double &price2)
{
//--- 如果第一点的时间没有设置，它将位于当前柱
if(!time1)
time1=TimeCurrent();
//--- 如果第一点的价格没有设置，则它将用卖价值
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- 如果第二点的时间没有设置，它则位于第二点左侧的9个柱
if(!time2)
{
//--- 接收最近10柱开盘时间的数组
datetime temp[10];
CopyTime(Symbol(),Period(),time1,10,temp);
//--- 在第一点左侧9柱设置第二点
time2=temp[0];
}
//--- 如果第二点的价格没有设置，则它与第一点的价格相等
if(!price2)
price2=price1;
}
//+------------------------------------------------------------------+
//| 脚本程序起始函数 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- 检查输入参数的正确性
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100)
{
Print("Error! Incorrect values of input parameters!");
return;
}
//--- 图表窗口的可见柱的数量
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- 价格数组大小
int accuracy=1000;
//--- 存储要使用的日期和价格值的数组
//--- 设置和改变线定位点的坐标
datetime date[];
double price[];
//--- 内存分配
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- 填写日期数组
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Failed to copy time values! Error code = ",GetLastError());
return;
}
//--- 填写价格数组
//--- 找出图表的最高值和最低值
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- 定义变化的价格并填写该数组
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- 定义画线的点
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
int p2=InpPrice2*(accuracy-1)/100;
//--- 创建箭头线
if(!ArrowedLineCreate(0,InpName,0,date[d1],price[p1],date[d2],price[p2],
InpColor,InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- 重画图表并等待1秒
ChartRedraw();
Sleep(1000);
//--- 现在，移动线的定位点
//--- 循环计数器
int v_steps=accuracy/5;
//--- 垂直移动第二个定位点
for(int i=0;i<v_steps;i++)
{
//--- 使用下面的值
if(p2<accuracy-1)
p2+=1;
//--- 移动点
if(!ArrowedLinePointChange(0,InpName,1,date[d2],price[p2]))
return;
//--- 检查脚本操作是否已经强制禁用
if(IsStopped())
return;
//--- 重画图表
ChartRedraw();
}
//--- 垂直移动第一个定位点
for(int i=0;i<v_steps;i++)
{
//--- 使用下面的值
if(p1>1)
p1-=1;
//--- 移动点
if(!ArrowedLinePointChange(0,InpName,0,date[d1],price[p1]))
return;
//--- 检查脚本操作是否已经强制禁用
if(IsStopped())
return;
//--- 重画图表
ChartRedraw();
}
//--- 半秒延迟
Sleep(500);
//--- 循环计数器
int h_steps=bars/2;
//--- 同时水平移动两个定位点
for(int i=0;i<h_steps;i++)
{
//--- 使用下面的值
if(d1<bars-1)
d1+=1;
if(d2>1)
d2-=1;
//--- 切换点
if(!ArrowedLinePointChange(0,InpName,0,date[d1],price[p1]))
return;
if(!ArrowedLinePointChange(0,InpName,1,date[d2],price[p2]))
return;
//--- 检查脚本操作是否已经强制禁用
if(IsStopped())
return;
//--- 重画图表
ChartRedraw();
// 0.03 秒延迟
Sleep(30);
}
//--- 1 秒延迟
Sleep(1000);
//--- 删除箭头线
ArrowedLineDelete(0,InpName);
ChartRedraw();
//--- 1 秒延迟
Sleep(1000);
//---
}