负二项式分布

这部分包含了处理负二项式分布的所有函数。它们可以计算密度，概率，四分位数以及生成根据负二项式定律分布的伪随机数。负二项式分布通过以下公式来定义：

在这里：

x — 随机变量值

r — 成功测试的数量

p — 成功的概率

除了计算单独的随机变量以外，程序库还具有处理随机变量数组的能力。

函数	描述
MathProbabilityDensityNegativeBinomial	计算负二项式分布的概率密度函数
MathCumulativeDistributionNegativeBinomial	计算负二项式概率分布函数值
MathQuantileNegativeBinomial	计算指定概率逆负二项式分布函数值
MathRandomNegativeBinomial	生成根据负二项式定律分布的伪随机变量/伪随机变量数组
MathMomentsNegativeBinomial	计算负二项式分布的前4力矩的理论数值

示例：

#include <Graphics\Graphic.mqh>

#include <Math\Stat\NegativeBinomial.mqh>

#include <Math\Stat\Math.mqh>

#property script_show_inputs

//--- 输入参数

input double n_par=40;        // 测试数

input double p_par=0.75;      // 每次测试的成功概率

//+------------------------------------------------------------------+

//| 脚本程序起始函数                                                   |

//+------------------------------------------------------------------+

void OnStart()

  {

//--- 隐藏价格图表

   ChartSetInteger(0,CHART_SHOW,false);

//--- 初始化随机数生成器  

   MathSrand(GetTickCount());

//--- 生成一个随机变量样本

   long chart=0;

   string name="GraphicNormal";

   int n=1000000;       // 样本值的数量

   int ncells=19;       // 直方图区间数

   double x[];          // 直方图的区间中心

   double y[];          // 区间内样本数量值下降

   double data[];       // 随机值样本

   double max,min;      // 样本的最大最小值

//--- 获得负二项式分布的样本

   MathRandomNegativeBinomial(n_par,p_par,n,data);

//--- 计算数据来绘制直方图

   CalculateHistogramArray(data,x,y,max,min,ncells);

//--- 获得[min,max]区间的理论计算数据

   double x2[];

   double y2[];

   MathSequence(0,n_par,1,x2);

   MathProbabilityDensityNegativeBinomial(x2,n_par,p_par,false,y2);

//--- 设定比例

   double theor_max=y2[ArrayMaximum(y2)];

   double sample_max=y[ArrayMaximum(y)];

   double k=sample_max/theor_max;

   for(int i=0; i<ncells; i++)

      y[i]/=k;

//--- 输出图表

   CGraphic graphic;

   if(ObjectFind(chart,name)<0)

      graphic.Create(chart,name,0,0,0,780,380);

   else

      graphic.Attach(chart,name);

   graphic.BackgroundMain(StringFormat("Negative Binomial distributionn n=%G p=%G",n_par,p_par));

   graphic.BackgroundMainSize(16);

//--- 绘制全部曲线

   graphic.CurveAdd(x,y,CURVE_HISTOGRAM,"Sample").HistogramWidth(6);

//--- 现在绘制分布密度的理论曲线

   graphic.CurveAdd(x2,y2,CURVE_LINES,"Theory").LinesSmooth(true);

   graphic.CurvePlotAll();

//--- 绘制全部曲线

   graphic.Update();

  }

//+------------------------------------------------------------------+

//|  计算数据集的频率                                                  |

//+------------------------------------------------------------------+

bool CalculateHistogramArray(const double &data[],double &intervals[],double &frequency[],

                             double &maxv,double &minv,const int cells=10)

  {

   if(cells<=1) return (false);

   int size=ArraySize(data);

   if(size<cells*10) return (false);

   minv=data[ArrayMinimum(data)];

   maxv=data[ArrayMaximum(data)];

   double range=maxv-minv;

   double width=range/cells;

   if(width==0) return false;

   ArrayResize(intervals,cells);

   ArrayResize(frequency,cells);

//--- 定义区间中心

   for(int i=0; i<cells; i++)

     {

      intervals[i]=minv+(i+0.5)*width;

      frequency[i]=0;

     }

//--- 填充区间内下降的频率

   for(int i=0; i<size; i++)

     {

      int ind=int((data[i]-minv)/width);

      if(ind>=cells) ind=cells-1;

      frequency[ind]++;

     }

   return (true);

  }